Using the NTK create a new project, for the example we will call it test locale.

Create a text file containing the following:

/*
**
**
**      This creates a locale bundle which changes the time format
**      to 24 hour format, and makes the day of the week & month of the
**      year appear appear in lower case text.
**
*/
constant kLocaleName := "Ausfix";


InstallScript :=
func(partFrame, removeFrame)
begin 
	local currentLocale := call kFindLocaleFunc with ("Australia");
	
	local newLocale := EnsureInternal ( {	// Have as internal so can survive card removal 
		_proto: nil,			// Create the slot name internal
		title: kLocaleName,		// Have to be internal, when do RemoveLocale, check for title match
		timeFormat: {
			_proto: nil,	
			timeCycle: kCycle12,	// change to 24 hour cycle
		},
		defaultPaperSize: 'a4,
		distanceMeasure: 'kilometers,
		distanceLabelShort: "km",
		distanceLabel:	"kilometers",
		speakerless: nil,
	});
		
	// Set proto's so get the built-in system slots and all the defaults
	newLocale._proto := currentLocale;		
	newLocale.timeFormat._proto := currentLocale.timeFormat;	
		
	// Done creating the locale, so add it to the system collection & set	
	call kAddLocaleFunc with (newLocale);	
	SetLocale(kLocaleName);			
	
	// Do EnsureInternal so if the card gets pulled, can clean up gracefully 
	removeFrame.(EnsureInternal('OldLocaleTitle)) := EnsureInternal(currentLocale.title);
end;

RemoveScript :=
func(removeFrame)
begin
 	SetLocale (removeFrame.OldLocaleTitle); 	
 	// If the OldLocale is no available, RemoveLocale will 
 	// pick the first built-in locale 
 	call kRemoveLocaleFunc with (kLocaleName);	 
end;

Select Project->Build to build the locale.

The package is then ready to download and you are done.